Max Eixo no Drill Down

[Valmir Braz]

Bom dia Pessoal.

Criei uma medida para utilizar no Eixo Y > Faixa > Maximo. Com objetivo de os rotulos não truncarem para dentro do grafico de das barras.




Este grafico de barras tem um drill down , Mes, Quinzena e Dia.

Fiz a medida abaixo. Porem quando faço o drill o valor não retorna o Max do contexto.

Max Eixo = 
VAR _Fator = 1*5
VAR _Mes = 
MAXX(
    ALLSELECTED(dCalendario[Mês Abv],dCalendario[Mês Num.]),
    [Venda Real]
) * _Fator

VAR _Quinzena = 
MAXX(
    ALLSELECTED(dCalendario[QuinzenaNum],dCalendario[QuinzenaNome]),
    [Venda Real]
) * _Fator

VAR _Dia = 
MAXX(
    ALLSELECTED(dCalendario[Dia]),
    [Venda Real]
) * _Fator

RETURN 
    SWITCH(
        TRUE(),
        ISINSCOPE(dCalendario[Mês Abv]),_Mes,
        ISINSCOPE(dCalendario[QuinzenaNome]),_Quinzena,
        ISINSCOPE(dCalendario[Dia]),_Dia
    )

Arquivo pbix em anexo.

Obrigado.

1-Sand Box.pbix

[Joao Raulino]

Boa @Valmir Braz!

Ainda falta tirar o contexto de cima do contexto que voce esta analisando no drill-down (e.g.: tirar o contexto do mes, quando estiver no nivel da semana).

Ficaria assim:

Citar

Max Eixo =

VAR _Fator = 5

VAR _Mes =

MAXX(

    ALLSELECTED(dCalendario[Mês Abv], dCalendario[Mês Num.]),

    [Venda Real]

) * _Fator

 

VAR _Quinzena =

MAXX(

    ALLSELECTED(dCalendario[QuinzenaNome], dCalendario[QuinzenaNum], dCalendario[Mês Abv], dCalendario[Mês Num.]),

    [Venda Real]

) * _Fator

 

VAR _Dia =

MAXX(

    ALLSELECTED(dCalendario[Dia], dCalendario[QuinzenaNome], dCalendario[QuinzenaNum], dCalendario[Mês Abv], dCalendario[Mês Num.]),

    [Venda Real]

) * _Fator

 

RETURN

    SWITCH(

        TRUE(),

        ISINSCOPE(dCalendario[Dia]),_Dia,

        ISINSCOPE(dCalendario[QuinzenaNome]),_Quinzena,

        ISINSCOPE(dCalendario[Mês Abv]),_Mes

    )

Abs!

[Joao Raulino]

Suave @Valmir Braz?

Tenta trocar a ordem no SWITCH:

Citar

RETURN 
    SWITCH(
        TRUE(),
        ISINSCOPE(dCalendario[Dia]),_Dia,
        ISINSCOPE(dCalendario[QuinzenaNome]),_Quinzena,
        ISINSCOPE(dCalendario[Mês Abv]),_Mes
    )

Abs!

[Valmir Braz]

12 horas atrás, Joao Raulino disse:

Suave @Valmir Braz?

Tenta trocar a ordem no SWITCH:

Abs!

Opa. Bom dia @Joao Raulino.
Troquei aorder do SWITCH e no nivel quinzena dia não fixa o mesmo valor para todos.

 

 

[Valmir Braz]

1 hora atrás, Joao Raulino disse:

Boa @Valmir Braz!

Ainda falta tirar o contexto de cima do contexto que voce esta analisando no drill-down (e.g.: tirar o contexto do mes, quando estiver no nivel da semana).

Ficaria assim:

Abs!

Top. Certinho @Joao Raulino. Obrigado

[Tiago Craici - Xperiun]

57 minutos atrás, Valmir Braz disse:

Top. Certinho @Joao Raulino. Obrigado

@Valmir Braz

 

Caso atendido seu objetivo, por gentileza marque a Melhor resposta para o tópico, para isso basta ir naquela que mais te ajudou e clicar nas opções conforme print: