Conversão de tabela do dax pra Liguagem M.

[Alaf Victor Martins]

Boa tarde pessoal tudo bem? possuo essa tabela em dax, Só que ela tem diferencial quando ele chega no final ela pega cinco dias anteriores ao dia Hoje e se repete, precisava converte isso em linguagem M mais, de toda forma que faço da errado será que você poderiam me dar uma ajuda. Vou colocar um print da tabela em anexo a parte do final pra vocês intenderem, e logica da mesma está abaixo.
 

Tabela_Datas =

ADDCOLUMNS (

    CALENDAR (DATE(2022,1,1), DATE(2023, 12, 31)),

    "D0", [Date],

    "Nome Data", FORMAT([Date], "yyyy MMMM dd"),

    "Nome Data 2", FORMAT([Date], "dd \d\e MMMM \d\e yyyy"),

    "Texto Dia", FORMAT([Date], "dd"),

    "Texto Mes", UPPER(FORMAT([Date], "MMMM")),

    "Texto Ano", FORMAT([Date], "yyyy"),

    "Offset Dias", SWITCH(

        DATEDIFF(TODAY(), [Date], DAY),

        -1, "-1",

        -2, "-2",

        -3, "-3",

        -4, "-4",

        -5, "-5"

    )

)

[Vitor Peralva]

Bom Dia, @Alaf Victor Martins!

 

Tente o seguinte código:

let
    DataInicial = #date(2022, 1, 1),
    DataFInal = #date(2023, 12, 31),
    QtdDias = Duration.Days(DataFInal - DataInicial) + 1,
    ListaDatas = List.Dates(DataInicial, QtdDias, #duration(1,0,0,0)),
    #"Convertido para Tabela" = Table.FromList(ListaDatas, Splitter.SplitByNothing(), null, null, ExtraValues.Error),
    #"Tipo Alterado" = Table.TransformColumnTypes(#"Convertido para Tabela",{{"Column1", type date}}),
    #"Colunas Renomeadas" = Table.RenameColumns(#"Tipo Alterado",{{"Column1", "Data"}}),
    #"Personalização Adicionada" = Table.AddColumn(#"Colunas Renomeadas", "D0", each [Data], type date),
    #"Personalização Adicionada1" = Table.AddColumn(#"Personalização Adicionada", "Nome Data", each Date.ToText([Data], "yyyy MMMM dd"), type text),
    #"Personalização Adicionada2" = Table.AddColumn(#"Personalização Adicionada1", "Nome Data 2", each Date.ToText([Data], "dd \d\e MMMM \d\e yyyy"), type text),
    #"Dia Inserido" = Table.AddColumn(#"Personalização Adicionada2", "Texto Dia", each Text.From(Date.Day([Data])), type text),
    #"Nome do Mês Inserido" = Table.AddColumn(#"Dia Inserido", "Texto Mês", each Text.Upper(Date.MonthName([Data])), type text),
    #"Ano Inserido" = Table.AddColumn(#"Nome do Mês Inserido", "Texto Ano", each Text.From(Date.Year([Data])), type text),
    #"Personalização Adicionada3" = Table.AddColumn(#"Ano Inserido", "Offset Dias", each let

vDifDias = Duration.Days([Data] - Date.From(DateTime.LocalNow())),
vResultado = if vDifDias < 0 and vDifDias >= -5 then vDifDias else null

in 

Text.From(vResultado), type text)
in
    #"Personalização Adicionada3"

 

Espero ter ajudado.

[Ezequiel Pedreira]

Fala @Alaf Victor Martins, de uma olhada neste vídeo, acredito que irá te ajudar.

https://youtu.be/O0xL4ve53Ns

[Alaf Victor Martins]

 

8 minutos atrás, Alaf Victor Martins disse:

Cara me expressei mal, não e pra repetir os números, era so pra jogar eles pra baixo, vou tentar alterar esse código aqui qualquer coisa te falo se conseguir algo me fala aqui tbm. 

 

[Julian Ferreira Salcedo]

Olá @Alaf Victor Martins tudo bem? 😃

Esperamos que você tenha encontrado a solução que tanto desejava!!

Caso alguma resposta tenha ajudado, você pode marcá-la como Solução ✅. Com isso o tópico poderá ser fechado! 

Maas...

Pode acontecer de você receber uma resposta que não é 100% do que você esperava. Mesmo assim, se ela o ajudou de alguma forma para que você mesmo conseguisse chegar à solução, conte como você fez isso e marque como a melhor resposta. 😉

 

Obrigado por tonar nossa comunidade #INCOMPARÁVEL!!

Att Julian Salcedo I Community Manager Xperiun

 

[Joao Raulino]

Suave @Alaf Victor Martins?

Da uma olhada no código do @Vitor Peralva que retorna exatamente o resultado que você precisa:

Se a resposta dele te ajudou, não se esqueça de marcar ela como melhor solução 😉

Abs!