Inserção de linha com totais em colunas específicas - Power Query

[Reginaldo Batista]

Bom dia pessoal, tudo bem?

Eu estou com uma tabela de resultados de pesagens de veículos, qual o meu cenário atual e qual o desejado? Bom deixe-me dizer...
Eu cheguei até  a etapa abaixo "Cenário Atual" depois de algumas modelagens e agrupar por. Mas preciso ainda de mais um detalhe, que numa nova etapa aplicada a tabela venha exatamente como o print abaixo "Cenário desejado" , onde uma nova linha será acrescida a tabela e nesta 5 colunas da tabela especificamente venham com os totais acrescidos.
Isso é um requisito do cliente, mas de toda forma estamos abertos a alternativas.

 

[Erick Oliveira]

Bom dia, Reginaldo;

Segue uma solução no power query para o resultado espero.

Seria interessante, se for possível, trabalhar sempre com tabelas dinâmicas, e lá colocar os totais.

 

let
    Fonte = Table.FromRows(
        Json.Document(
            Binary.Decompress(
                Binary.FromText(
                    "XVDLasQwDPwXQ2+G6mE9/B09hj2ksIUG2kJf37+S06TJnmY0ZsYjTVNZ5vdHApRSCwoKBKoQB7iSBcCBVngIePpY5nKpU3m5/u5eQsB0qZmlRZhazsQ8R
                    ujjudV2inibP7cIYgjroNqE1jhUJQGgoKyoPiRxd26jEJ3S5uc9LeoosmdtcofIC2bk4GrjWUNOCa2J9ZSq3FV73cKEG60Vo0ti72PG7ukk66xZu+opYfn
                    5vy342MdEM4BJ+O+2G7277df1e/c2Wa/ifSyh4+8jPXovNw==",
                    BinaryEncoding.Base64
                ),
                Compression.Deflate
            )
        ),
        let
            _t = ((type nullable text) meta [Serialized.Text = true])
        in
            type table [
                #"Nome do Mês" = _t,
                #"Bruto (kg)" = _t,
                #"Tara (kg)" = _t,
                #"Subtotal (kg)" = _t,
                #"Descontos (kg)" = _t,
                #"Líquido (kg)" = _t,
                #"% Desconto" = _t,
                Produto = _t
            ]
    ),
    #"Tipo Alterado" = Table.TransformColumnTypes(
        Fonte,
        {
            {"Nome do Mês", type text},
            {"Bruto (kg)", Int64.Type},
            {"Tara (kg)", Int64.Type},
            {"Subtotal (kg)", Int64.Type},
            {"Descontos (kg)", Int64.Type},
            {"Líquido (kg)", Int64.Type},
            {"% Desconto", Percentage.Type},
            {"Produto", type text}
        }
    ),
    #"Linhas Agrupadas" = Table.Group(
        #"Tipo Alterado",
        {},
        {
            {"Bruto (kg)", each List.Sum([#"Bruto (kg)"]), type nullable number},
            {"Tara (kg)", each List.Sum([#"Tara (kg)"]), type nullable number},
            {"Subtotal (kg)", each List.Sum([#"Subtotal (kg)"]), type nullable number},
            {"Descontos (kg)", each List.Sum([#"Descontos (kg)"]), type nullable number},
            {"Líquido (kg)", each List.Sum([#"Líquido (kg)"]), type nullable number}
        }
    ),
    #"Personalização Adicionada" = Table.AddColumn(#"Linhas Agrupadas", "Nome do Mês", each "Total:", type text),
    #"Consulta Acrescentada" = Table.Combine({#"Tipo Alterado", #"Personalização Adicionada"})
in
    #"Consulta Acrescentada"

 

[Reginaldo Batista]

anexando o arquivo de exemplo

Reginaldo Batista PQ.xlsx

[Reginaldo Batista]

Te chamei no privado @Erick Oliveira

[Reginaldo Batista]

Solução atendida! Obrigado @Erick Oliveira 🤜🤛