Importação de arquivos

[Diego.fs]

Boa tarde!

Como devo proceder para importar 4 arquivos diferentes em excel, onde cada arquivo contém 5 planilhas diferentes e em cada planilha consta 1 tabela dinâmica com  a vendas mensais de diferentes produtos ao longo do ano?

 

 

SalesArmando2013[1].xlsx

[Maycon Silva]

Boa tarde tudo bem?

Eu geralmente faço assim:

Seleciono 1 aba inicialmente da planilha e clico em transformar dados.

 

Após excluo as etapas e mantenho somente a etapa de fonte, excluo as demais colunas deixando somente as 2 primeiras, daí expando a coluna data.

 

[Vitor Peralva]

Boa Tarde, @Diego.fs!

 

Tenta assim:

 

Insere numa consulta nula esta função e renomeia ela para fxTrataPlanilha:

 

(Tabela as table) =>

let

    #"Personalização Adicionada" = Table.AddColumn(Tabela, "Personalizar", each [
Categoria = Tabela[Column2]{0},
País = Tabela[Column2]{1},
Supervisor = Tabela[Column2]{2},
Ano = Tabela[Column2]{3}
]),
    #"Linhas Superiores Removidas" = Table.Skip(#"Personalização Adicionada",6),
    #"Cabeçalhos Promovidos" = Table.PromoteHeaders(#"Linhas Superiores Removidas", [PromoteAllScalars=true]),
    #"Colunas Removidas" = Table.RemoveColumns(#"Cabeçalhos Promovidos",{"Total Geral"}),
    #"Linhas Filtradas" = Table.SelectRows(#"Colunas Removidas", each ([Rótulos de Linha] <> "Total Geral")),
    #"Outras Colunas Não Dinâmicas" = Table.UnpivotOtherColumns(#"Linhas Filtradas", {"Rótulos de Linha", "Column15"}, "Mês", "Valor"),
    #"Column15 Expandido" = Table.ExpandRecordColumn(#"Outras Colunas Não Dinâmicas", "Column15", {"Categoria", "País", "Supervisor", "Ano"}, {"Categoria", "País", "Supervisor", "Ano"})
in
    #"Column15 Expandido"

 

E você vai aplicar ela no seu arquivo.

O meu código ficou assim:

let
    Fonte = Excel.Workbook(File.Contents("C:\Users\vitor\Downloads\SalesArmando2013[1].xlsx"), null, true),
    #"Outras Colunas Removidas" = Table.SelectColumns(Fonte,{"Data"}),
    #"Função Personalizada Invocada" = Table.AddColumn(#"Outras Colunas Removidas", "fxTrataPlanilha", each fxTrataPlanilha([Data])),
    #"Outras Colunas Removidas1" = Table.SelectColumns(#"Função Personalizada Invocada",{"fxTrataPlanilha"}),
    #"fxTrataPlanilha Expandido" = Table.ExpandTableColumn(#"Outras Colunas Removidas1", "fxTrataPlanilha", {"Rótulos de Linha", "Categoria", "País", "Supervisor", "Ano", "Mês", "Valor"}, {"Rótulos de Linha", "Categoria", "País", "Supervisor", "Ano", "Mês", "Valor"})
in
    #"fxTrataPlanilha Expandido"

 

Aí bastaria alterar o endereço do arquivo.

 

Espero que tenha ajudado.

[Diego.fs]

Boa tarde!

 

Gratidão Vitor