Tipagem não vem após expansão de coluna personalizada adicionada

[Alison Pezzott]

Opa galera, tudo bem!
Por favor, alguém sabe como resolver a questão onde as colunas expandidas que foram adicionadas por uma função personalizada não carregam o tipo dos dados (data, number, text etc...) que foram definidos na criação da função?

[Erick Oliveira]

Bom dia Alison;
Precisa ao chamar a função precisa definir a coluna como tipo table e colocar as especificações das linhas:

let
  
    source = Database,

    out = Table.Combine(
        let
            t_armando = Excel.Workbook(source{[#"Folder Path"= FolderAdress,Name="SalesArmando2013.xlsx"]}[Content]),
            t_helton = Excel.Workbook(source{[#"Folder Path"= FolderAdress,Name="SalesHelton2013.xlsx"]}[Content]),
            t_joseph = Excel.Workbook(source{[#"Folder Path"= FolderAdress,Name="SalesJoseph2013.xlsx"]}[Content]),
            t_xavier = Excel.Workbook(source{[#"Folder Path"= FolderAdress,Name="SalesXavier2013.xlsx"]}[Content])
        in
            {t_armando, t_helton , t_joseph, t_xavier }           
    ),

    #"Removed Other Columns" = Table.SelectColumns(out,{"Data"}),
    #"Invoked Custom Function" = Table.AddColumn(
        #"Removed Other Columns", 
        "fxSalesEachVendor", 
        each fxSalesEachVendor([Data]),
        type table [
            Subcategory Name= text, 
            Net Sales= number, 
            Category Name= text, 
            Supervisor= text, 
            Date= date
            ]
    ),

    #"Removed Columns" = Table.RemoveColumns(#"Invoked Custom Function",{"Data"}),
    #"Expanded {0}" = Table.ExpandTableColumn(
        #"Removed Columns", 
        "fxSalesEachVendor", 
        {"Subcategory Name", "Net Sales", "Category Name", "Supervisor", "Date"}, 
        {"Subcategory Name", "Net Sales", "Category Name", "Supervisor", "Date"}
    )
in
    #"Expanded {0}"

 

[Renato Carlos Rossato]

Olá @Alison Pezzott, adiciona um PBIX de exemplo aqui pra nós podermos te ajudar melhor.

[Alison Pezzott]

1 hora atrás, Renato Rossato disse:

Olá @Alison Pezzott, adiciona um PBIX de exemplo aqui pra nós podermos te ajudar melhor.

Opa Renato, segue.

Não se ficou claro o que eu coloquei, mas em tese a última etapa da SupervisorSales eu não precisaria "tipar" novamente pq já fiz isso na função.

Não é nenhum problema gravíssimo, é mais TOC mesmo...rs.

SalesArmando2013.xlsx SalesHelton2013.xlsx SalesJoseph2013.xlsx Salesperson.pbix SalesXavier2013.xlsx