Média dos últimos 12 meses + Média com critério no denominador

[Jeferson Souza]

Pessoal, eu preciso fazer a média de vendas de vários SKUs, 

Porém terão meses que não terei venda, como um dos produtos em anexo que tenho venda apenas em 10 meses.


como faço pra criar um dax que identifique quantos meses de venda tenho para SKU x e faça a média por este número e não somente fixando a média por 12?


é possível eu alterar o denominador de acordo com a quantidade de meses que tenho de venda para cada produto ?

 

 

Teste.pbix

[Bruno Abdalla de Souza]

OU esta solução aqui

Media Vendas Ultimos 12m = 
VAR vAnoMesFim = MAX(dCalendario[AnoMesNum])
VAR vAnoMesIni = vAnoMesFim - 11
VAR vUltimos12MesesComVendas = 
    FILTER(
        ALL(dCalendario[AnoMesNum], dCalendario[Ano], dCalendario[Mês], dCalendario[Nome do Mês]),
        dCalendario[AnoMesNum] <= vAnoMesFim && 
        dCalendario[AnoMesNum] >= vAnoMesIni && 
        NOT(ISBLANK([Total Vendas]))
    )
VAR vResultado = 
    AVERAGEX(
        vUltimos12MesesComVendas,
        [Total Vendas]
    )
RETURN
    vResultado

 

20230119_Teste.pbix

[Bruno Abdalla de Souza]

Veja se isso ajuda:

Media Vendas = 
VAR vUltimos12Meses =
    ADDCOLUMNS(
        SUMMARIZE(
            fVendas,
            dCalendario[Ano], 
            dCalendario[Mês], 
            dCalendario[Nome do Mês],
            fVendas[SKU]
        ),
        "Vendas",
        [Total Vendas]
    )
VAR vResultado = 
    AVERAGEX(
        vUltimos12Meses,
        [Vendas]
    )
RETURN
    vResultado

 

20230119_Teste.pbix

[Jeferson Souza]

12 horas atrás, Bruno Abdalla de Souza disse:

OU esta solução aqui

Media Vendas Ultimos 12m = 
VAR vAnoMesFim = MAX(dCalendario[AnoMesNum])
VAR vAnoMesIni = vAnoMesFim - 11
VAR vUltimos12MesesComVendas = 
    FILTER(
        ALL(dCalendario[AnoMesNum], dCalendario[Ano], dCalendario[Mês], dCalendario[Nome do Mês]),
        dCalendario[AnoMesNum] <= vAnoMesFim && 
        dCalendario[AnoMesNum] >= vAnoMesIni && 
        NOT(ISBLANK([Total Vendas]))
    )
VAR vResultado = 
    AVERAGEX(
        vUltimos12MesesComVendas,
        [Total Vendas]
    )
RETURN
    vResultado

 

20230119_Teste.pbix 60.18 kB · 1 download

Boa noite!
deu certo, muito obrigado pela ajuda amigo!