Contagem de dias sem atendimento

[renanfelipes]

Olá Pessoal. Uma dúvida de lógica aqui. 

Preciso fazer um calculo de dependência de suporte técnico, onde me falta uma parte da medida.

quantidade de dias sem atendimento, onde a lógica é esta:  IF( [Qtd Atendimentos] = 0 && SELECTEDVALUE(dCalendario[Dia válido]) = 1, somar os dias)

ou seja no exemplo abaixo o resultado precisa ser 6. Para quando for filtrado um mês em específico seja exibido o percentual de 72,72% de dependência.

 

[alexsander.silva]

Vê se te atende:


É isso que você precisa ou o 6 tem que se repetir em todas as linhas?

[alexsander.silva]

4 minutos atrás, renanfelipes disse:

Olá Pessoal. Uma dúvida de lógica aqui. 

Preciso fazer um calculo de dependência de suporte técnico, onde me falta uma parte da medida.

quantidade de dias sem atendimento, onde a lógica é esta:  IF( [Qtd Atendimentos] = 0 && SELECTEDVALUE(dCalendario[Dia válido]) = 1, somar os dias)

ou seja no exemplo abaixo o resultado precisa ser 6. Para quando for filtrado um mês em específico seja exibido o percentual de 72,72% de dependência.

 

Bom dia,
Favor anexar um pbix de exemplo por favor.

[Edson Igari]

@renanfelipes, blz. Se entendi direito, tenta isso:
Dias_Sem_atend = 
SUMX(
        VALUES(ID_DATA),
         IF( [Qtd Atendimentos] = 0 && SELECTEDVALUE(dCalendario[Dia válido]) = 1, 1,0)
)

se não der certo, anexa um pbix um excel. Assim fica mais fácil de ajudar.

[Tiago Craici]

Bom dia @renanfelipes! Da uma olhada veja se ajuda:

renan.pbix

[renanfelipes]

Olá Pessoal, de momento as soluções não atenderam a necessidade. Estou encaminhando uma base para testes.

 

duvida.pbix

[Tiago Craici]

Fiquei com essa dúvida também... 🤔

[alexsander.silva]

Caso queira o 6 em todas as linhas eu consegui utilizando esta medida:
 

DiasSemAtend = 
VAR vMes =
    MONTH(
        SELECTEDVALUE(dCalendario[ID_DATA])
    )
VAR vDiaInicial = 
    CALCULATE(
        MIN(dCalendario[Dia]),
        ALL(dCalendario),
        dCalendario[Mês] = vMes
    )
VAR vDiaFinal = 
    CALCULATE(
        MAX(dCalendario[Dia]),
        ALL(dCalendario),
        dCalendario[Mês] = vMes
    )
VAR vDiasSemAtend =
    CALCULATE(
        COUNTROWS(
            FILTER(
                dCalendario,
                [Qtd Atendimentos] = 0 && [Dia válido] = 1
            )
        ),
        dCalendario[Mês] = vMes,
        dCalendario[Dia] >= vDiaInicial && dCalendario[Dia] <= vDiaFinal
    )
RETURN
IF(
    HASONEVALUE(dCalendario[ID_DATA]),
    vDiasSemAtend,
    CALCULATE(
        COUNT(dCalendario[ID_DATA]),
        FILTER(
            dCalendario,
            [Qtd Atendimentos] = 0 && [Dia válido] = 1
        )
    )
)

Não sei se é a melhor maneira de fazer, mas é uma possível solução.

[renanfelipes]

@Tiago Craici ,  @alexsander.silva e @edigari Muito obrigado pela ajuda de todos.

A resolução do colega @alexsander.silva conseguiu contemplar a necessidade.

 

Segue abaixo a medida completa para curiosidade cientifica, trecho da dúvida está destacado:

 

Grau de Dependência = 
var vDiasUteisMes = 
CALCULATE(
    CALCULATE(
        COUNTROWS(dCalendario),
        dCalendario[Dia válido] = 1
    ),
    ALL(dCalendario),
    VALUES(dCalendario[Ano]),
    VALUES(dCalendario[Mês])
)

var vDiasSemAtend = 
CALCULATE(
    COUNT(dCalendario[ID_DATA]),
    FILTER(
        dCalendario,
        [Qtd Atendimentos] = 0 && [Dia válido] = 1
    )
)

return 

1 - DIVIDE(vDiasSemAtend, vDiasUteisMes)

[alexsander.silva]

5 minutos atrás, renanfelipes disse:

@Tiago Craici ,  @alexsander.silva e @edigari Muito obrigado pela ajuda de todos.

A resolução do colega @alexsander.silva conseguiu contemplar a necessidade.

 

Segue abaixo a medida completa para curiosidade cientifica, trecho da dúvida está destacado:

 

Grau de Dependência = 
var vDiasUteisMes = 
CALCULATE(
    CALCULATE(
        COUNTROWS(dCalendario),
        dCalendario[Dia válido] = 1
    ),
    ALL(dCalendario),
    VALUES(dCalendario[Ano]),
    VALUES(dCalendario[Mês])
)

var vDiasSemAtend = 
CALCULATE(
    COUNT(dCalendario[ID_DATA]),
    FILTER(
        dCalendario,
        [Qtd Atendimentos] = 0 && [Dia válido] = 1
    )
)

return 

1 - DIVIDE(vDiasSemAtend, vDiasUteisMes)

Obrigado, fico feliz em ajudar.