Nova Coluna Linguagem M ou DAX - buscando o N° máximo de um processo com + de 1 item e níveis de atendimento distintos.

[Thiago Annibal de Oliveira]

Pessoal, boa tarde.


Precisando muito da ajuda de vocês. 

 

Tenho uma base de dados em anexo, ontem existem pedidos finalizados, pontuando se estão NO PRAZO ou VENCIDO.

A definição de estar no prazo ou não, vem dos níveis de dias para cada tipo de produto.

Porém, desta forma, um pedido com mais de 1 item pode ter 2 status.

 

Preciso ter uma coluna, onde mostra o nível de dia máximo para todos os itens do mesmo processo, assim, cada processo fica com apenas 1 status: VENCIDO ou NO PRAZO.

 

Podem me ajudar?

Pode ser uma coluna no POWER QUERY (LINGUAGEM M) OU NO  POWER BI (LINGUAGEM DAX).

 

 

BASE PARA TESTE.xlsx

[Bruno Abdalla de Souza]

Se quiser via DAX, use esta coluna calculada:

NOVO_NIVEL DAX = 
    VAR vPedido = [PEDIDO]
    VAR vNivelMax = 
        CALCULATE(
            MAX(Tabela1[NIVEL ATENDIMENTO]),
            FILTER(
                ALL(Tabela1),
                Tabela1[PEDIDO] = vPedido
            )
        )
RETURN
    vNivelMax

 

[Bruno Abdalla de Souza]

O status é por pedido apenas ou por pedido e ID Produto? Se puder indicar qual o resultado desejado, ajudaria a entender a regra.

[Thiago Annibal de Oliveira]

Bom dia Bruno, por PEDIDO apenas.

Se um pedido tem 5 itens, eu gostaria que o nível de atendimento fosse o maior numero do nível de atendimento inicial.

 

Ja que os níveis de atendimento atual é por item, eu apenas gostaria de uma regra que buscasse o maior numero para deixar apenas um nível de atendimento.

 

Editado Junho 2, 2022 por Thiago Annibal de Oliveira

[Thiago Annibal de Oliveira]

@Bruno Abdalla de Souza

Segue a tabela com a ultima coluna, que é o desejo a ser alcançado.

 

[Bruno Abdalla de Souza]

Veja se atende.

NovaColunaNivelMaxPorItem.pbix

[Thiago Annibal de Oliveira]

@Bruno Abdalla de Souza
Atende sim!

É isso mesmo, porem não estou conseguindo o acesso ao power query porque a planilha não está em minha maquina, 

 

Quando mudo a fonte para a minha maquina, some a coluna que vc fez.

 

[Thiago Annibal de Oliveira]

Consegue me mandar uma foto, ou a formula, ou explicar como fez?

 

[Bruno Abdalla de Souza]

Baixa a planilha que vc anexou no fórum e muda o caminho da fonte para pegar da pasta do seu computador.

[Bruno Abdalla de Souza]

Usei este código no PowerQuery

let
    Fonte = Excel.Workbook(File.Contents("C:\Downloads\BASEPARATESTE.xlsx"), null, true),
    Tabela1_Table = Fonte{[Item="Tabela1",Kind="Table"]}[Data],
    AlteraTipoDados = Table.TransformColumnTypes(Tabela1_Table,{{"PROCESSOS", Int64.Type}, {"PEDIDO", Int64.Type}, {"ID PRODUTO", Int64.Type}, {"DATA ABERTURA", type date}, {"NIVEL ATENDIMENTO", Int64.Type}, {"DATA FINALIZAÇÃO", type date}, {"DIAS EM ABERTO", Int64.Type}, {"STATUS", type text}, {"NOVO NIVEL - POR PEDIDO ????", type any}}),
    #"Linhas Agrupadas" = Table.Group(AlteraTipoDados, {"PEDIDO"}, {{"NOVO NIVEL ATENDIMENTO", each List.Max([NIVEL ATENDIMENTO]), type nullable number}}),
    #"Consultas Mescladas" = Table.NestedJoin(AlteraTipoDados, {"PEDIDO"}, #"Linhas Agrupadas", {"PEDIDO"}, "Linhas Agrupadas", JoinKind.LeftOuter),
    #"Linhas Agrupadas Expandido" = Table.ExpandTableColumn(#"Consultas Mescladas", "Linhas Agrupadas", {"NOVO NIVEL ATENDIMENTO"}, {"NOVO NIVEL ATENDIMENTO"})
in
    #"Linhas Agrupadas Expandido"

 

Editado Junho 2, 2022 por Bruno Abdalla de Souza

[Thiago Annibal de Oliveira]

Muito Obrigado @Bruno Abdalla de Souza

Resolveu muito...

 

Obrigado!!