Ajuste de Medidas (Hora) + Ajuste de Totais

[Carlos Eduardo Silva]

Boa tarde!

Tenho uma medida que estou calculando as horas de um jeito diferente da maioria (SUMX). Consigo chegar no mesmo resultado que preciso. Contudo, preciso entender alguns fatores que acabam atrapalhando para concluir o raciocínio da minha conta.

Quero multiplicar valores por hora. Aqui eu uso o valor inteiro para o cálculo. É possível fazer sem usar o inteiro? Ex 18:30 x 25,3

Quando eu retorno na tabela o valor da VAR _Horas, ela retorna o total na matriz. Quando quero retornar a VAR _Perdas, ela me retorna outro valor (Peças Produzidas), e as outras VAR estão ficando sem o total e não entendi o pq.

Segue o modelo em anexo.

forum (3).pbix

[Bruno Abdalla de Souza]

Veja agora:

PROJEÇÃO PERDAS = 
VAR _IDEAL =
    SUMX(
        SUMMARIZE(
            'LANÇAMENTOS',
            'LANÇAMENTOS'[PEÇAS],
            "Disp",
            SUM('LANÇAMENTOS'[DISPONÍVEIS]) * 24
        ),
        VAR vPecas = [PEÇAS]
        VAR vIdeal = 
            SWITCH(
                vPecas,
                "COLARINHO", 16,
                "COLUNA", 26,
                "FRONTAL", 14,
                "RESERVATÓRIO", 16,
                "RÉGUA", 80,
                "TAMPA", 20
            )
        VAR vHoras = [Disp]
        RETURN
        vHoras * vIdeal
    )
VAR _PERDAS = _IDEAL - [PEÇAS PRODUZIDAS]
VAR _RESULT = 
    DIVIDE(
        _IDEAL - [PEÇAS PRODUZIDAS],
        _IDEAL
    )
RETURN
_RESULT

 

20241015_forum.pbix

[Bruno Abdalla de Souza]

Veja se é isso.

PROJEÇÃO PERDAS = 
VAR _IDEAL =
    SUMX(
        SUMMARIZE(
            'LANÇAMENTOS',
            'LANÇAMENTOS'[DISPONÍVEIS],
            'LANÇAMENTOS'[PEÇAS]
        ),
        VAR vPecas = [PEÇAS]
        VAR vIdeal = 
            SWITCH(
                vPecas,
                "COLARINHO", 16,
                "COLUNA", 26,
                "FRONTAL", 14,
                "RESERVATÓRIO", 16,
                "RÉGUA", 80,
                "TAMPA", 20
            )
        VAR vDisponiveis = [DISPONÍVEIS]
        VAR vHoras = 
        DIVIDE(
            HOUR(vDisponiveis) * 3600 +
            MINUTE(vDisponiveis) * 60 +
            SECOND(vDisponiveis),
            3600
        )
        RETURN
        vIdeal * vHoras
    )
VAR _PERDAS = _IDEAL - [PEÇAS PRODUZIDAS]
VAR _RESULT = 
    DIVIDE(
        _IDEAL - [PEÇAS PRODUZIDAS],
        _IDEAL
    )
RETURN
_RESULT

 

20241015_forum.pbix

[Carlos Eduardo Silva]

Bruno, bom dia! Vc já virou o guru das minhas dúvidas. Preciso validar as informações mas do jeito que vc montou não estou conseguindo. Deixa eu tentar explicar:

Do jeito que montei, se comparar em uma tabela Horas disponíveis x VAR _Horas, retorna o mesmo valor de horas. Se tenho 30 horas disponíveis a uma produtividade de 16pç horas (colarinho), daria um valor ideal de 480 e isso se repete para cada produto. Olhando para o mês de Ago/2024. Isso eu teria um total de 1327 e no seu total 88.

É possível deixar as VAR separadas para que eu possa fazer essa validação?

Estou deixando um exemplo de como retorna o valor do meu _Ideal x o seu _Ideal, e um exemplo de como seria a minha _Perdas x a sua _Perdas

[Bruno Abdalla de Souza]

Neste caso não dá para deixar separado,  pois os cálculos devem ser feitos linha a linha dentro da SUMX.

[Carlos Eduardo Silva]

Perfeito como sempre Bruno! Muito obrigado! Apenas fico com as dúvidas:

1- O que estava errado na minha lógica para não retornar os totais?

2- O pq de dar um RETURN dentro da SUMX? Não sei se tem essas aulas na Xperium, mas é um aprendizado novo a cada ideia que eu tenho!

[Bruno Abdalla de Souza]

1- O que estava errado na minha lógica para não retornar os totais?

R: Porque na linha de total o resultado dá errado. Você precisa percorrer cada linha, calcular as horas e o valor ideal, multiplicar para no final somar. Se vc fizer separado em cada variável, na linha de total ele vai multiplicar a soma do ideal pela soma das horas e isso não é verdade.

2- O pq de dar um RETURN dentro da SUMX? Não sei se tem essas aulas na Xperium, mas é um aprendizado novo a cada ideia que eu tenho!

R: O RETURN foi usado porque usei variáveis dentro da SUMX para calcular cada cálculo necessário por etapas. Quando uso variável, tenho que no final usar o RETURN, não importa se dentro ou fora de uma função.