Especificar em coluna dia HOJE na Dcalendário "TRUE" e "FALSE "

[Isaias_Ribeiro]

Bom dia pessoal, tudo bem ?

Queria na Dcalendário ter uma coluna que especificasse o "Dia de hoje"  em TRUE e FALSE.  Já tenho uma Dcalendário construida, só não sei como adicionar no editor avançado para essa coluna aparecer. Quando o for o dia de Hoje aparecer  "TRUE" e os restante dos dias aparecer "FALSE"

Segue código> 
 

MenorData = List.Min (fVendas.Ingressos[data_venda]),
    MaiorData = List.Max (fVendas.Ingressos[data_venda]),
    
//Não alterar daqui pra baixo    
    
    DataInicio = Date.StartOfYear(MenorData),
    DataFim = Date.EndOfYear(MaiorData),
    Dias = Duration.Days(DataFim- DataInicio) +1,
    ListarDatas = List.Dates(DataInicio, Dias, #duration(1,0,0,0)),
    Tabela = #table(
        type table[
            Data = date,
            Ano = Int64.Type,
            NomeMes = text,
            MesAbre = text,
            MesAno = text,
            MesNum = number,
            AnoMesINT = number,
            InicioMes = date,
            Trimestre = Int64.Type,
            TrimestreAbreviado = text,
            Bimestre = text,
            Semestre = text,
            Semana = Int64.Type,
            DiaSemana = Int64.Type,
            NomeDia = text,
            Passado = logical,
            AnoAtual = text,
            MesAtual = text
        ],
        List.Transform(
            ListarDatas,
            each {
                _,
                Date.Year(_),
                Text.Proper( Date.MonthName(_)),
                Text.Proper(Text.Start(Date.MonthName(_), 3)),
                Text.Proper(Text.Start(Date.MonthName(_), 3)) & "-" & Text.End(Text.From(Date.Year(_)), 2),
                Date.Month(_),
                Date.Year(_) * 100 + Date.Month(_),
                Date.StartOfMonth(_),
                Date.QuarterOfYear(_),
                Text.From(Date.QuarterOfYear(_)) & "º Trim ",
                Text.From( Number.RoundUp( Date.Month(_)/2,0)) & "º Bim",
                Text.From( Number.RoundUp( Date.Month(_)/6,0)) & "º Sem",
                Date.WeekOfMonth(_),
                Date.DayOfWeek(_),
                Date.DayOfWeekName(_),
                if _ <= MaiorData then true else false,
                if Date.IsInCurrentYear(_) then "Ano Atual" else Text.From(Date.Year(_)),
                if Date.IsInCurrentYear(_) and Date.IsInCurrentMonth(_) then "Mês Atual" else Text.Proper( Date.MonthName(_))
            }

        )
    ),
    #"Primeiros Caracteres Inseridos" = Table.AddColumn(Tabela, "DiaSemanaAbrev", each Text.Start(Text.Proper([NomeDia]), 3), type text),
    #"Dias inseridos no Mês" = Table.AddColumn(#"Primeiros Caracteres Inseridos", "Dias do Mês", each Date.DaysInMonth([Data]), Int64.Type)
in
    #"Dias inseridos no Mês"

[Edson Igari]

Veja se é isso. Só remover os comentários.

 

let
MenorData = List.Min (fVendas.Ingressos[data_venda]),
    MaiorData = List.Max (fVendas.Ingressos[data_venda]),
    
//Não alterar daqui pra baixo    
    
    DataInicio = #date(2024,01,01),//Date.StartOfYear(MenorData),
    DataFim = #date(2024,12,31),//Date.EndOfYear(MaiorData),
    Dias = Duration.Days(DataFim- DataInicio) +1,
    ListarDatas = List.Dates(DataInicio, Dias, #duration(1,0,0,0)),
    Tabela = #table(
        type table[
            Data = date,
            Ano = Int64.Type,
            NomeMes = text,
            MesAbre = text,
            MesAno = text,
            MesNum = number,
            AnoMesINT = number,
            InicioMes = date,
            Trimestre = Int64.Type,
            TrimestreAbreviado = text,
            Bimestre = text,
            Semestre = text,
            Semana = Int64.Type,
            DiaSemana = Int64.Type,
            NomeDia = text,
            Passado = logical,
            AnoAtual = text,
            MesAtual = text
        ],
        List.Transform(
            ListarDatas,
            each {
                _,
                Date.Year(_),
                Text.Proper( Date.MonthName(_)),
                Text.Proper(Text.Start(Date.MonthName(_), 3)),
                Text.Proper(Text.Start(Date.MonthName(_), 3)) & "-" & Text.End(Text.From(Date.Year(_)), 2),
                Date.Month(_),
                Date.Year(_) * 100 + Date.Month(_),
                Date.StartOfMonth(_),
                Date.QuarterOfYear(_),
                Text.From(Date.QuarterOfYear(_)) & "º Trim ",
                Text.From( Number.RoundUp( Date.Month(_)/2,0)) & "º Bim",
                Text.From( Number.RoundUp( Date.Month(_)/6,0)) & "º Sem",
                Date.WeekOfMonth(_),
                Date.DayOfWeek(_),
                Date.DayOfWeekName(_),
                if _ <= MaiorData then true else false,
                if Date.IsInCurrentYear(_) then "Ano Atual" else Text.From(Date.Year(_)),
                if Date.IsInCurrentYear(_) and Date.IsInCurrentMonth(_) then "Mês Atual" else Text.Proper( Date.MonthName(_))
            }

        )
    ),
    #"Primeiros Caracteres Inseridos" = Table.AddColumn(Tabela, "DiaSemanaAbrev", each Text.Start(Text.Proper([NomeDia]), 3), type text),
    #"Dias inseridos no Mês" = Table.AddColumn(#"Primeiros Caracteres Inseridos", "Dias do Mês", each Date.DaysInMonth([Data]), Int64.Type),
    #"Personalização Adicionada" = Table.AddColumn(#"Dias inseridos no Mês", "FILTRO", each if #date(Date.Year(DateTime.LocalNow()),Date.Month(DateTime.LocalNow()),Date.Day(DateTime.LocalNow())) = [Data] then true else false)
in
    #"Personalização Adicionada"

[Isaias_Ribeiro]

Deu certo! Obrigado meu amigo! 

[Edson Igari]

Por nada.