Contagem de dias úteis com feriados regionais

[Henrique de Albuquerque]

Boa tarde,

Preciso de uma ajuda com o seguinte problema: tenho uma tabela calendário e uma tabela desconectada com os feriados Estaduais.  Preciso criar uma medida  (Chamei de Days) que retorne os dias úteis num período x (selecionado pelo usuário) de acordo com os estados, mesmo que não haja venda para esses estados. Tecnicamente uma contagem simples.

Por exemplo no Período do dia 01-maio-2023 à 07-maio-2023 São 5 dias úteis, porém na minha tabela de Feriados, Queensland e Tasmania tem feriados nos dias 01-maio e 05-maio respectivamente, dessa forma para esses dois estados deveriam apresentar o valor de 4 dias úteis nesse período.

Por favor, alguem consegue me dar uma luz no que eu estou fazendo errado aqui?

Anexei um arquivo de exemplo pra ficar mais fácil. 

Desde já muito Obrigado

Minhas medidas: 

Revenue = SUM(financials[ Sales])

------------------------
Days = // Essa é a medida que preciso de Ajuda
 VAR _holidays = CALCULATETABLE(SELECTCOLUMNS(dHolidays,"Date", dHolidays[Date]),dHolidays[States] in VALUES(financials[State]))
 RETURN  NETWORKDAYS(MIN(dCalendar[Date]),MAX(dCalendar[Date]),1,_holidays) 

----------------
Budget per Day = 
SUMX( SUMMARIZE(financials, financials[State]),
CALCULATE(
DIVIDE(
    SUMX(
        financials,
        [Revenue]
    ),
    SUMX(
         VALUES(financials[State]),
        [Days]
    )
)))

Retorno nesse momento (Errado): 

Resultado esperado:

 

Calendar and Different Holidays.pbix Financial Sample.xlsx Holidays Australia.xlsx

[Henrique de Albuquerque]

Rodolfo Muito Obrigado.

Deu Certo! Valeu meu amigo!

[Davi Rodolfo]

Falai Henrique, veja se é isso aqui que vc precisa
Segue pbix com a solução em anexo
Obs:  tive que ligar a State na Financials e colocar o campo States[States] em Linhas na Matriz pra medida funcionar corretamente

Days2 =

VAR DataInicial = MIN( dCalendar[Date] )

VAR DataFinal = MAX( dCalendar[Date] )

VAR EstadoSelecionado = MAX( States[States] )

VAR FeriadosEstado =

    FILTER(

        dHolidays

        , dHolidays[States] = EstadoSelecionado

)

VAR FeriadosPeriodo =

    FILTER(

        FeriadosEstado

        , dHolidays[Date] >= DataInicial && dHolidays[Date] <= DataFinal

)

VAR DiasUteis =

    COUNTROWS(

        FILTER(

            GENERATESERIES( DataInicial , DataFinal , 1 )

            , WEEKDAY( [Value] , 2 ) < 6  -- Considera apenas dias úteis (segunda a sexta)

            && COUNTROWS(

                FILTER(

                    FeriadosPeriodo      -- Considera apenas Feriados dos estados

                    , [Value] = dHolidays[Date]

                    )

                ) = 0

        )

    )

RETURN DiasUteis



 

Calendar and Different Holidays.pbix