Saldo de Estoque

[Rafael_Oliveira]

Boa tarde Pessoal

Tenho as seguintes dax:

Qtd Compras = SUM(COMPRAS[QTD])
Qtd Vendas = SUM(VENDAS[QTD])
Qtd Estoque Inicial = 
CALCULATE(
    SUM(PRODUTOS_COMPLETO[saldo_contabil]),
    USERELATIONSHIP(dCalendario[Data], PRODUTOS_COMPLETO[DATA])
)
Saldo Estoque = ([Qtd Estoque Inicial] + [Qtd Compras]) - [Qtd Vendas]

a matriz gerada foi essa:


o que eu estou fazendo errado?, alguém pode me ajudar?

Desde já, obrigado.

[Bruno Abdalla de Souza]

Você precisa acumular a compra e as vendas do início até a data de contexto e aí somar com o estoque inicial.

 

Qtd Compras = 
	VAR vDataIni = 
		CALCULATE(
			MIN(dCalendario[Data]),
			ALLSELECTED(dCalendario[Data])
		)
	VAR vDataContexto = 
		MAX(dCalendario[Data])
	VAR vResultado = 
		CALCULATE(
			SUM(COMPRAS[QTD]),
            FILTER(
              ALL(dCalendario[Data]),
              dCalendario[Data] >= vDataIni && 
              dCalendario[Data] <= vDataContexto
			)
		)
RETURN
	vResultado
                                               
Qtd Vendas = 
	VAR vDataIni = 
		CALCULATE(
			MIN(dCalendario[Data]),
			ALLSELECTED(dCalendario[Data])
		)
	VAR vDataContexto = 
		MAX(dCalendario[Data])
	VAR vResultado = 
		CALCULATE(
			SUM(VENDAS[QTD]),
            FILTER(
              ALL(dCalendario[Data]),
              dCalendario[Data] >= vDataIni && 
              dCalendario[Data] <= vDataContexto
			)
		)
RETURN
	vResultado

Qtd Estoque Inicial = 
CALCULATE(
    SUM(PRODUTOS_COMPLETO[saldo_contabil]),
    USERELATIONSHIP(dCalendario[Data], PRODUTOS_COMPLETO[DATA]),
	ALLSELECTED(dCalendario[Data])
)
                                               
Saldo Estoque = ([Qtd Estoque Inicial] + [Qtd Compras]) - [Qtd Vendas]

Tenta isso. Se não der, anexa o pbix, por favor.

[Rafael_Oliveira]

Obrigado pela Ajuda.

[Bruno Abdalla de Souza]

De nada @Rafael_Oliveira.