Mostrar o último mês quando não é usado filtro

[getswitch]

Bom dia

Tenho uma dashboard que mostra alguns dados financeiros de todos os empreendimentos, nela tenho filtros por "Empreendimento" e por "Mês/Ano". Gostaria de saber como posso fazer para quando não estiver utilizando nenhum filtro de "Mês/Ano", mostrar nos cards e gráficos os valores do mês mais atual, ao invés de mostrar o total de todos os meses.

[Tiago Craici - Xperiun]

@getswitch Opção sem utilizar filtro lateral:

Medida:



Tiago ultimo mes =
VAR vUltimaVenda =  //pega a última data da sua tabela fato
    CALCULATE ( MAXX ( fVendas, fVendas[dia] ), ALL ( fVendas ) )
    
VAR vMesUltimaVenda =  //pega o último mês da sua tabela fato
    MONTH ( vUltimaVenda )
    
VAR vAnoUltimaVenda =  //pega o último ano da sua fato
    YEAR ( vUltimaVenda )
    
    
RETURN 
    IF (
        ISFILTERED ( dCalendario[Mes Abrev] ), 
        [Total Venda],
        CALCULATE (
            [Total Venda],
            ALL ( dCalendario ),
            dCalendario[Ano] = vAnoUltimaVenda,
            dCalendario[Mes] = vMesUltimaVenda
        )
    )




Exemplo aplicado a uma medida total vendido, mesma lógica aplica-se para qualquer outra medida. 



Sucesso! 🚀
 

[FelipeHulle]

Olá @getswitch, crie :

flag =
IF (
    ISFILTERED ( 'calendar'[MonthNo] ),
    IF (
        MONTH ( SELECTEDVALUE ( FATO[Date] ) )
            = SELECTEDVALUE ( 'calendar'[MonthNo] ),
        1,
        0
    ),
    IF (
        MONTH ( SELECTEDVALUE (FATO'[Date] ) )
            = MONTH ( TODAY () ) ,
        1,
        0
    )
)

 

Coloque essa medida flag no filtro a nivel de visual onde você quer que aconteça isso e coloque 1 no filtro (exemplo abaixo)

[getswitch]

Em 31/05/2023 em 21:07, Tiago Craici disse:

@getswitch Opção sem utilizar filtro lateral:

Medida:



Tiago ultimo mes =
VAR vUltimaVenda =  //pega a última data da sua tabela fato
    CALCULATE ( MAXX ( fVendas, fVendas[dia] ), ALL ( fVendas ) )
    
VAR vMesUltimaVenda =  //pega o último mês da sua tabela fato
    MONTH ( vUltimaVenda )
    
VAR vAnoUltimaVenda =  //pega o último ano da sua fato
    YEAR ( vUltimaVenda )
    
    
RETURN 
    IF (
        ISFILTERED ( dCalendario[Mes Abrev] ), 
        [Total Venda],
        CALCULATE (
            [Total Venda],
            ALL ( dCalendario ),
            dCalendario[Ano] = vAnoUltimaVenda,
            dCalendario[Mes] = vMesUltimaVenda
        )
    )




Exemplo aplicado a uma medida total vendido, mesma lógica aplica-se para qualquer outra medida. 



Sucesso! 🚀
 

Deu certo, muito obrigado pela ajuda. 🙂